;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Sprite Block
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

db $42
JMP MarioBelow : JMP MarioAbove : JMP MarioSide : JMP SpriteV : JMP SpriteH : JMP MarioCape : JMP MarioFireBall : JMP MarioCorner : JMP BodyInside : JMP HeadInside

!SpriteToGenerate   = $1C

   ;; RAM addresses
   !RAM_BlockYLo     = $98
   !RAM_BlockYHi     = $99
   !RAM_BlockXLo     = $9A
   !RAM_BlockXHi     = $9B
   !RAM_SpriteYLo    = $D8
   !RAM_SpriteXLo     = $E4
   !RAM_SpriteYHi    = $14D4
   !RAM_SpriteXHi     = $14E0
   !RAM_EffectSprNum  = $17C0
   !RAM_EffectSprY     = $17C4
   !RAM_EffectSprX     = $17C8
   !RAM_EffectSprTimer = $17CC
   
   ;; JSL locations
   !FindFreeSlotLowPri   = $02A9DE
   !InitSpriteTables   = $07F7D2
   !GenerateTile      = $00BEB0
   
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

MarioFireBall:
   PHB             
        PHK             
        PLB
   PHX

        JSL !FindFreeSlotLowPri   ; X = free sprite slot
        BMI Return
        TYX     
   
   LDA #!SpriteToGenerate   ; Store sprite number
        STA $9E,x 
        JSL !InitSpriteTables   ; Reset sprite tables

        LDA #$01      ; Sprite status = Init
        STA $14C8,x

   LDA !RAM_BlockXLo   ; Sprite position = block position
   STA !RAM_SpriteXLo,x
   LDA !RAM_BlockXHi
   STA !RAM_SpriteXHi,x
   LDA !RAM_BlockYLo
   STA !RAM_SpriteYLo,x   
   LDA !RAM_BlockYHi
   STA !RAM_SpriteYHi,x 
   
   LDA #$02      ; Replace block with blank tile
   STA $9C
   JSL !GenerateTile

   LDY #$03                ; Find a free slot to display effect
FindFreeSlot:   
   LDA !RAM_EffectSprNum,y
   BEQ ShowSmoke   
   DEY                     
   BPL FindFreeSlot   
   BRA Return

ShowSmoke:
   LDA #$01          ; Set effect graphic to smoke graphic       
   STA !RAM_EffectSprNum,y 
   LDA #$1B                ; Set time to show smoke             
   STA !RAM_EffectSprTimer,y

   LDA !RAM_BlockXLo   ; Smoke position = block position
   STA !RAM_EffectSprX,y
   LDA !RAM_BlockYLo
   STA !RAM_EffectSprY,y 

Return:
   PLX
   PLB
BodyInside:
HeadInside:
MarioBelow:
MarioAbove:
MarioSide:
MarioCorner:
SpriteV:
SpriteH:
MarioCape:
   RTL